**; QTheory.docx CSC148**

; QTheory.gps 2018 version

; Models for computing ss stats of: exponential and hypoexponential degree n

; service distributions in Kendall M/M/1 and M/G/1 models. This model extends the Reference

; Manual model named QTHEORY.GPS, by G. F. Cummings.

; gpssW Report format facilitates display of relationships among (above) model results

; Revision#3 - Feb 2018, WJM Add tr Arrivals\_freq\_tr and histogram of L samples

; Revision#2 - August 2017, WJM Add QTABLE to get L^ and W^ stats

; The focus of this model is simulation validation of various M/M/1 ss formulas

; Example W = 1 / ( mu \* (1-rho)) = 1 / ( (1/300)\*(4/10) ) = 750 t.u.

; = 7.5 simulated seconds.

; Revision#1 - June 2013, WJM Add doc for QTABLE statement

; A QTABLE statement creates a histogram with the same structure Operands B,C, and D

; as does a TABLE statement; the A Operand specifies the name of the operand for the

; corresponding queue/depart pair.

; There is no need for TABULATE blocks because stats are automatically collected only

; at the (fixed) location of the of corresponding queue/depart pair. The stats are ONLY

; for the region between the queue/depart.

; TABLE/TABULATE is more flexible: TABULATE can appear anywhere in a tr's

; blocks, and A Operand specifies an arbitrary expression.

; ++++++++++++++++++++++++++

; This model compares residence, and service stats for Exponential, Erlang (degree 3),

; and hypoexponential Distributions

; Time Unit Is 1/100 Of a Second

; Usage: WJM mods.: START x; when n arrivals tr types are active, on average, x/n

; arrivals will occur, per tr type; Model termination: tc <-- 0

;

; To check Little's Law for a given service distribution, comment out all other tr types,

; thus, executing only tr of one desired type.

\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

CLEAR

iaMean EQU 500 ; Interarrivals mean

Arrivals\_timebase EQU iaMean ; Sampling frequency for ss statistic L

serviceMean EQU 300 ; Service duration mean

RMULT 1985493

QexpServiceDur QTABLE exp\_svr,200,200,20 ; exponential service duration Histogram

QexpW QTABLE expW,200,200,20 ; exponential residence Histogram

QerlangServiceDur QTABLE erlang\_svr,200,200,20 ; Erlang, degree 3 service duration histogram

QerlangW QTABLE erlangW,200,200,20 ; Erlang residence Histogram

QffServiceDur QTABLE ff\_svr,100,100,30 ; Fast Food service distribution

sampleL TABLE v$currentL,0,1,10 ; Histogram of sample L values

;currentL VARIABLE (q$erlangW) ; Number of cj in S (same as L^ sample)

;currentL VARIABLE (q$expW)

currentL VARIABLE (q$ffW)

\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

;PureExp GENERATE (Exponential(1,0,iaMean)) ;Interarrival 5 seconds

QUEUE expW ; Start gathering residence stats

QUEUE expon\_wait ; Start gathering service wait stats

SEIZE Facility2 ; Acquired server

DEPART expon\_wait ; Finish gathering service wait stats

QUEUE exp\_svr ; Start gathering service durations stats

ADVANCE (Exponential(1,0,serviceMean)) ; Mean service duration 3 seconds

RELEASE Facility2

DEPART exp\_svr ; Finish gathering service duration stats

DEPART expW ; Finish gathering residence stats

TERMINATE 1 ; Customer leaves S

\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

fastFood GENERATE (Exponential(1,0,iaMean)) ;Interarrival time 5 secs

; This tr simulates typical service modeling at a Fast Food (FF) drive through;

; Service is 3-stage hypoExponential; windows have different exponential distr means

QUEUE FFW ; Start gathering residence stats

; Define a "black box" facility for the total/overall service, not individual stages

; This model does NOT represent sub-queuing for each service window, nor the “pipeline”

; nature of a sequence of service windows

SEIZE SVR

SEIZE ff3

QUEUE ff\_svr

ADVANCE (Exponential(1,0,serviceMean/6)) ; Order food

RELEASE ff3

queue ff4\_svr ; Measure waiting for Facility4

SEIZE ff4

depart ff4\_svr

ADVANCE (Exponential(1,0,serviceMean/3)) ; Pay for food

RELEASE ff4

SEIZE ff5

ADVANCE (Exponential(1,0,serviceMean/3)) ; Get food and leave

RELEASE ff5

DEPART ff\_svr

DEPART ffW ; Finish gathering residence stats

RELEASE SVR

TERMINATE 1 ; Customer leaves S

; NOTE: An Erlang service is NOT implemented, nor Reported

;Erlang\_n GENERATE (Exponential(1,0,iaMean)) ;Interarrival time 5 secs

QUEUE erlangW ; Start gathering residence stats

SEIZE Facility3

QUEUE erlang\_svr

ADVANCE (Exponential(1,0,serviceMean/3)) ;Erlang degree n=3

RELEASE Facility3

queue fac4\_svr ; Measure waiting for Facility4

SEIZE Facility4

depart fac4\_svr

ADVANCE (Exponential(1,0,serviceMean/3))

RELEASE Facility4

SEIZE Facility5

ADVANCE (Exponential(1,0,serviceMean/3))

RELEASE Facility5

DEPART erlang\_svr

DEPART erlangW ; Finish gathering residence stats

TERMINATE 1 ; Customer leaves S

; tr samples current value of L every Arrivals\_timebase time units

Arrivals\_freq\_tr GENERATE Arrivals\_timebase

TABULATE sampleL

TERMINATE

**Exponential service model –** 100000 cj pure Kendall M/M/1

FACILITY ENTRIES UTIL. AVE. TIME AVAIL. OWNER PEND INTER RETRY DELAY

FACILITY2 100001 **0.601** **300.312** 1 199984 0 0 0 0

QUEUE MAX CONT. ENTRY ENTRY(0) AVE.CONT. AVE.TIME AVE.(-0) RETRY

EXP\_SVR 1 0 100000 0 0.601 **300.315** 300.315 0 **Service duration**


EXPW 21 1 100001 0 1.484 **741.632** 741.632 0 **Wcj**

ERLANG\_SVR 0 0 0 0 0.000 0.000 0.000 0

ERLANGW 0 0 0 0 0.000 0.000 0.000 0

EXPON\_WAIT 20 1 100001 39931 0.883 441.320 734.684 0

**Some distributions**



The (service duration) and W distributions display properties and typical shape of an exponentially distributed pmf, and the S.D. and means agree closely, as they should. However, the L distribution is, parametrically, not exp distributed; it combines waiting and service processing.

**Hypoexponential service distribution – 3 stages Kendall M/G/1 – Relationship to Homework#3A service “Steps”**

This distribution differs from Erlang of the same degree (number of stages) in that the stages have different means. The asymmetry yields a different distribution shape from Erlang of the same degree.

FACILITY ENTRIES UTIL. AVE. TIME AVAIL. OWNER PEND INTER RETRY DELAY

SVR 100000 0.501 **250.493** 1 0 0 0 0 0

FF3 100000 0.100 50.085 1 0 0 0 0 0

FF4 100000 0.201 100.410 1 0 0 0 0 0

FF5 100000 0.200 99.998 1 0 0 0 0 0

QUEUE MAX CONT. ENTRY ENTRY(0) AVE.CONT. AVE.TIME AVE.(-0) RETRY

FF\_SVR 1 0 100000 0 **0.501 250.493** 250.493 0 *<- Removed stats for*

FFW 11 0 100000 0 **0.848 423.820** 423.820 0 *servers in inactive tr types*

FF4\_SVR 1 0 100000 100000 **0.000 0.000** 0.000 0

The QFFSERVICEDUR histogram of hypoexponential service duration exhibits less symmetry than Erlang of the same degree. Even though continuous, the histo. renders its appearance as very similar to a (discrete) Poisson distribution.

A 3-window homework#2 service has a similar histogram (fewer windows would have fewer distribution nodes (local high points)). Your distribution will depend on station mean values.

